Option Explicit

'-------------------------------------------------------------------------
' massuser.vbs
'
' Beschreibung: Erstellt massenhaft Benutzer mit Exchange Mailboxen
' '
' Laufzeitfehler werde nicht abgefangen und beenden das Skript.
' Das Skript wird mit den Berechtigungen des angemeldeten Benutzers
' ausgeführt. Die entsprechenden Berechtigungen sind sicher zu stellen
'
' (c)2004 Frank Carius, www.msxfaq.de
' Version 1.0 (19. Sep 2004)
'		+ Erste Version
'-------------------------------------------------------------------------

Dim i, username
Dim objRootDSE, objContainer, objusr

WScript.Echo WScript.ScriptName & " wurde gestartet."

If WScript.Arguments.Count=0 Then
	WScript.echo ("Bitte OU und Anzahl angeben")
	WScript.quit(255)
End If

If 		(WScript.Arguments.item(1)>999999) _
	OR  (WScript.Arguments.item(1) < 1 ) Then
	WScript.echo ("Bitte zwischen 1 und 999999 User anlegen")
	WScript.quit(255)
End If

Set objRootDSE = GetObject("LDAP://rootDSE")
Set objContainer = GetObject("LDAP://"& WScript.Arguments.Item(0))

For i = 1 To WScript.Arguments.Item(1)
	username= Replace(Space(5-Int(Log(i)/Log(10)))," ","0") & i  ' führende Nullen
	WScript.stdout.Write "Schreibe Massuser, " & username
	Set objusr = objContainer.Create("User", "cn=massuser-" & username)
' Allgemeine AD Informationen
	objusr.put "sAMAccountName", "massuser-" & username
	objusr.givenName = username
	objusr.sn = "massuser"
' Exchange Aktivierung
	objusr.displayName = "Massuser, " & username 
	objusr.mailnickname = "massuser-" & username
	objusr.homeMDB = "CN=Postfachspeicher (SRV01),CN=Erste Speichergruppe,CN=InformationStore,CN=SRV01,CN=Servers,CN=Erste administrative Gruppe,CN=Administrative Groups,CN=Msxfaq,CN=Microsoft Exchange,CN=Services,CN=Configuration,DC=msxfaq,DC=local"
' Und schreiben !!
	objusr.SetInfo
	objusr.AccountDisabled = False 
'	objusr.setPassword "Password!"
	objusr.SetInfo
	WScript.echo " - DONE"
Next
WScript.Echo i-1 & " Benutzer angelegt."
WScript.quit(0)